Progetto:WikiDonne/SPARQL: differenze tra le versioni
Contenuto cancellato Contenuto aggiunto
Donne nell'ambito medico |
Annullata la modifica 132727560 di Sod1123 (discussione) ripristinare il vandalismo Etichetta: Annulla |
||
| (31 versioni intermedie di 3 utenti non mostrate) | |||
Riga 2:
'''Esempi di [https://query.wikidata.org/ query SPARQL in WikiData].'''
'''Template WikiData list
<code>
Riga 18:
{{Wikidata list end}}</nowiki><br/>
</code>
== Item, titolo e genere delle voci in una categoria ==
{{SPARQL|query=
# Utilizzare l'API MediaWiki per ottenere gli articoli da una categoria specifica in una versione specifica della lingua di Wikipedia.
# Quindi utilizzare questi risultati come di consueto in una query, in questo esempio una semplice query per il sesso.
# Autore Utente:Ainali con l'aiuto dell'Utente:Dipsacus fullonum 2021-02
SELECT ?item ?itemLabel ?genderLabel WHERE {
SERVICE wikibase:mwapi {
bd:serviceParam wikibase:endpoint "it.wikipedia.org"; # progetto
wikibase:api "Generator";
mwapi:generator "categorymembers"; # contenuto di una categoria
mwapi:gcmtitle "Categoria:Giusti tra le nazioni italiani";. # specificare la categoria (Q8557798)
?item wikibase:apiOutputItem mwapi:item.
}
FILTER BOUND (?item) # evitare il timeout da elementi non vincolati quando si utilizza ?elemento di seguito
?item wdt:P21 ?gender . # esempio di recupero di un valore
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
}}
== Numero di visualizzazioni delle voci di una categoria ==
{{SPARQL|query=
#titolo: Visualizzazioni di pagina per tutti gli articoli in una categoria
SELECT ?title ?pageviews ?date WHERE {
VALUES ?item { wd:Q8557798 } # Categoria:Giusti tra le nazioni italiani (Q8557798)
?sitelink schema:about ?item ;
schema:isPartOf <https://it.wikipedia.org/> ; # itwiki
schema:name ?name .
SERVICE wikibase:mwapi {
bd:serviceParam wikibase:api "Generator";
wikibase:endpoint "it.wikipedia.org"; # itwiki
mwapi:generator "categorymembers";
mwapi:prop "pageviews";
mwapi:gcmtitle ?name ;
mwapi:pvipdays "1"; # Quanti giorni indietro nel tempo per ottenere le visualizzazioni della pagina
mwapi:gcmlimit "500". # nr. max di voci come risultato
?title wikibase:apiOutput mwapi:title .
?pageviews wikibase:apiOutput "pageviews/pvip/text()".
?date wikibase:apiOutput "pageviews/pvip/@date" .
}
FILTER(?pageviews != "1") # Filters out results with no views
} ORDER BY DESC(xsd:integer(?pageviews))
}}
== Artiste afghane mancanti in itwiki (V2) ==
{{SPARQL|query=SELECT ?item ?p27Label ?p19Label ?p20Label ?linkcount WHERE {
?item wdt:P21 wd:Q6581072 . #donna
?item wdt:P31 wd:Q5 . #essere umano
?item wdt:P106 ?occ . #occupazione
VALUES ?occ {
wd:Q33999 #attrice
wd:Q177220 #cantante
wd:Q36834 #compositrice
wd:Q2490358 #coreografa
wd:Q5716684 #danzatrice
wd:Q214917 #drammaturga (autrice teatrale)
wd:Q487596 #drammaturga (consigliera per la drammaturgia di uno spettacolo)
wd:Q33231 #fotografa
wd:Q11496048 #fotografa di guerra
wd:Q21694268 #fotoamatrice
wd:Q3381574 #fotografa d'architettura
wd:Q20743434 #fotografa di scena
wd:Q5864475 #fotografa pubblicitaria
wd:Q644687 #illustratrice
wd:Q715301 #fumettista
wd:Q15296811 #disegnatrice
wd:Q947873 #presentatrice tv
wd:Q2722764 #spaker radio
wd:Q245068 #attrice comica
wd:Q18545066 #attrice di stand-up comedy
wd:Q1028181 #pittrice
wd:Q47494964 #miniaturista
wd:Q47494964 #artista visual
wd:Q1281618 #scultrice
}
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P27 ?p27}
OPTIONAL {?item wdt:P19 ?p19}
OPTIONAL {?item wdt:P20 ?p20}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 100
}}
== Partigiane italiane presenti in itwiki (V2) ==
{{SPARQL|query=SELECT ?item ?linkcount WHERE {
?item wdt:P31 wd:Q5; #essere umano
wdt:P21 wd:Q6581072; #donna
wdt:P106 wd:Q212948; #partigiana
wdt:P27 wd:Q38; #paese di cittadinanza Italia
FILTER EXISTS { #ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
#FILTER (?linkcount > 3 ) .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
}}
== [[Progetto:WikiDonne/Liste voci mancanti/Partigiane e combattenti|Partigiane e combattenti mancanti in itwiki (V2)]] ==
{{SPARQL|query=SELECT ?item ?linkcount WHERE {
?item wdt:P31 wd:Q5; #essere umano
wdt:P21 wd:Q6581072; #donna
wdt:P106 wd:Q212948 . #partigiana
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
#FILTER (?linkcount > 3 ) .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
}}
== Biografie di folcloriste/etnologhe/etnomusicologhe mancanti in itwiki con più di 3 sitelink (V2) ==
{{SPARQL|query=SELECT ?item ?itemLabel ?occ ?occLabel ?image ?linkcount WHERE {
?item wdt:P21 wd:Q6581072 . #donna
?item wdt:P31 wd:Q5 . #essere umano
?item wdt:P106 ?occ .
VALUES ?occ {
wd:Q3075052 #folclorista
wd:Q1371378 #etnologa
wd:Q12347522 #etnografa
wd:Q17484288 #etnomusicologa
wd:Q32518759 #etnobotanica
}
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
OPTIONAL {?item wikibase:sitelinks ?linkcount .} #numero versioni linguistiche
FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P18 ?image}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 1000
}}
== Biografie di donne - voci in vetrina - mancanti in Wikiquote in italiano ==
Biografie di donne che sono voci in vetrina in varie lingue che partecipano alla campagna #SheSaid (en, es, fr, it, uk), ma non hanno una voce in Wikiquote in italiano.
{{SPARQL|query=SELECT DISTINCT ?item ?itemLabel ?FAsitelink ?WQsitelink
WHERE
{
?item wdt:P31 wd:Q5.
?item wdt:P21 wd:Q6581072 .
?FAsitelink # esiste una voce di Wikipedia in vetrina
schema:about ?item;
wikibase:badge wd:Q17437796 . # Sitelink voci in vetrina in it, en, fr, es, uk
{
?FAsitelink schema:isPartOf <https://it.wikipedia.org/> .
}
UNION
{ ?FAsitelink schema:isPartOf <https://en.wikipedia.org/> .}
UNION
{ ?FAsitelink schema:isPartOf <https://fr.wikipedia.org/> .}
UNION
{ ?FAsitelink schema:isPartOf <https://es.wikipedia.org/> .}
UNION
{ ?FAsitelink schema:isPartOf <https://uk.wikipedia.org/> .}
MINUS
{
?WQsitelink # meno i sitelink già esistenti in itwq
schema:about ?item ;
schema:isPartOf <https://it.wikiquote.org/>.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it" }
}
ORDER BY ASC(?itemLabel) #ordine ascendente della label
}}
== Lista crateri di Venus ==
{{SPARQL|query=SELECT ?item ?itemLabel ?image
WHERE
{
?item wdt:P31 wd:Q55818 . #entità cratere
?item wdt:P376 wd:Q313 . #situato sull'oggetto astronomico: pianeta Venus
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
OPTIONAL {?item wdt:P18 ?image .} #ha o no un'image
}
ORDER BY ASC(?itemLabel) #ordine ascendente della label
}}
== Donne nell'industria della moda (con label in lingue che utilizzano alfabeto non latino) ==
{{SPARQL|query=SELECT ?item ?itemLabel_ar ?itemLabel_bn ?itemLabel_he ?itemLabel_it ?linkcount WHERE {
?item wdt:P106 ?occ .
VALUES ?occ {
wd:Q3501317 #stiliste
wd:Q4610556 #modelle
wd:Q19698265 #fotografe di moda
wd:Q9397629 #giornali di moda
wd:Q11460 #abbigliamento
wd:Q28823 #tessile
wd:Q5436782 #musei di moda
wd:Q2090555 #negozi di abbigliamento
wd:Q1065579 #accessori
wd:Q11828862 #industria di abbigliamento
wd:Q22676 #scarpe
wd:Q7500021 #negozio di scarpe
}
FILTER NOT EXISTS { #non ha la voce in it.wikipedia
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wdt:P21 wd:Q6581072 . #genere donna
?item wdt:P31 wd:Q5 . #istanza umano
OPTIONAL {?item wikibase:sitelinks ?linkcount .} #numero di sitelinks
OPTIONAL {?item rdfs:label ?itemLabel_ar filter (lang(?itemLabel_ar) = "ar").} #label in ar se esiste
OPTIONAL {?item rdfs:label ?itemLabel_bn filter (lang(?itemLabel_bn) = "bn").} #label in bn se esiste
OPTIONAL {?item rdfs:label ?itemLabel_he filter (lang(?itemLabel_he) = "he").} #label in he se esiste
OPTIONAL {?item rdfs:label ?itemLabel_it filter (lang(?itemLabel_it) = "it").} #label in it se esiste
}
ORDER BY DESC(?linkcount) #in ordine decrescente per il numero di sitelinks
LIMIT 8000 #limite di 8000 items (numero max per il tool Listeria)
}}
== Donne di professione personale sanitario di emergenza nate dopo il 1 gennaio 1800 ==
{{SPARQL|query=SELECT ?item ?itemLabel ?image ?dateOfBirth ?dateOfDeath ?age ?linkCount
WHERE {
?item wdt:P31 wd:Q5; #istanza umano
wdt:P21 wd:Q6581072; #sesso donna
wdt:P569 ?birthDate; #data di nascita
wdt:P106 ?occ . #occupazione/professione
VALUES ?occ {
wd:Q28837 #anestesista-animatore
wd:Q336641 #medico di primo/pronto soccorso
}
FILTER (?dateOfBirth > "1800-01-01"^^xsd:dateTime) . #data di nascita dopo il 1 gen 1800
?sitelink schema:about ?item .
FILTER NOT EXISTS {
?wfr schema:about ?item .
?wfr schema:inLanguage "it" #voce non esistente in itwiki
}
SERVICE wikibase:label {
bd:serviceParam wikibase:language "it,en,es,fr,hy" . #label in varie lingue
}
OPTIONAL {?item wdt:P569 ?dateOfBirth .} #ha o no la data di nascita
OPTIONAL {?item wdt:P570 ?dateOfDeath .} #ha o no la data di morte
BIND(YEAR(?dateOfDeath) - YEAR(?dateOfBirth) as ?age) #calcolo età
OPTIONAL {?item wdt:P18 ?image .} #ha o no l'immagine
OPTIONAL {?item wikibase:sitelinks ?linkcount .} #ha o no numero sitelinks
}
}}
== [[Progetto:WikiDonne/Liste voci mancanti/Partecipanti ai Giochi Olimpici e Paralimpici|Sportive partecipanti agli ultimi 5 giochi olimpici e paralimpici]] (V2) ==
{{SPARQL|query=# sportive partecipanti agli ultimi 5 giochi olimpici e paralimpici (estivi e invernali) le cui voci mancano in itwiki (Listeria V2)
=SELECT DISTINCT ?item ?p27Label ?p19Label ?p20Label ?p1344Label ?linkcount
WHERE {
?item wdt:P31 wd:Q5 . #istanza di umano
?item wdt:P21 wd:Q6581072 . #genere donna
?item wdt:P1344 ?p1344 . #partecipante a
VALUES ?p1344 {
wd:Q5389 #Giochi olimpici
wd:Q159821 #Giochi olimpici estivi
wd:Q82414 #Giochi olimpici invernali
wd:Q73633 #Giochi paralimpici
wd:Q3327913 #Giochi paralimpici estivi
wd:Q3317976 #Giochi paralimpici invernali
wd:Q8613 #Giochi della XXXI Olimpiade (2016)
wd:Q8577 #Giochi della XXX Olimpiade (2012)
wd:Q8567 #Giochi della XXIX Olimpiade (2008)
wd:Q8558 #Giochi della XXVIII Olimpiade (2004)
wd:Q8544 #Giochi della XXVII Olimpiade (2000
wd:Q1142161 #XV Giochi paralimpici estivi (2016)
wd:Q182798 #XIV Giochi paralimpici estivi (2012)
wd:Q216864 #XIII Giochi paralimpici estivi (2008)
wd:Q840654 #XII Giochi paralimpici estivi (2004)
wd:Q855688 #XI Giochi paralimpici estivi (2000)
wd:Q487313 #XII Giochi paralimpici invernali (2018)
wd:Q1045816 #XI Giochi paralimpici invernali (2014)
wd:Q641965 #X Giochi paralimpici invernali (2010)
wd:Q749605 #IX Giochi paralimpici invernali (2006)
wd:Q591627 #VIII Giochi paralimpici invernali (2002)
}
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P27 ?p27}
OPTIONAL {?item wdt:P19 ?p19}
OPTIONAL {?item wdt:P20 ?p20}
OPTIONAL {?item wdt:P1344 ?p1344}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 1000
}}
== [[Progetto:WikiDonne/Liste voci mancanti/Sportive vincitrici di medaglie olimpiche e paralimpiche|Sportive vincitrici di medaglie olimpiche e paralimpiche, oro, argento e bronzo]] (V2) ==
{{SPARQL|query=# sportive vincitrici di medaglie olimpiche e paralimpiche le cui voci mancano in itwiki (Listeria V2)
SELECT DISTINCT ?item ?p27Label ?p19Label ?p20Label ?p166Label ?linkcount
WHERE {
?item wdt:P31 wd:Q5 . # istanza di umano
?item wdt:P21 wd:Q6581072 . # genere donna
?item wdt:P166 ?medal . # vincitrici di medaglie
VALUES ?medal {
wd:Q636830 # medaglie olimpiche
wd:Q15243428 # medaglie paralimpiche
wd:Q406039 # medaglie d'oro
wd:Q847956 # medaglie d'argento
wd:Q873364 # medaglie di bronzo
}
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
#FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P27 ?p27}
OPTIONAL {?item wdt:P19 ?p19}
OPTIONAL {?item wdt:P20 ?p20}
OPTIONAL {?item wdt:P166 ?p166}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 1000
}}
== [[Progetto:WikiDonne/Liste voci mancanti/Sportive vincitrici di medaglie in varie discipline|Sportive vincitrici di medaglie in varie discipline]] (V2) ==
{{SPARQL|query=SELECT DISTINCT ?item ?p27Label ?p19Label ?p20Label ?p166Label ?linkcount
WHERE {
?item wdt:P31 wd:Q5 . # istanza di umano
?item wdt:P21 wd:Q6581072 . # genere donna
?item wdt:P106 ?prof .
VALUES ?prof {
wd:Q3951423 # arrampicatrice
wd:Q9149093 # alpinista
wd:Q819677 # guida alpina
wd:Q11513337 # atletica leggera
wd:Q2066131 # atleta
wd:Q10843402 # nuotatrice
wd:Q16947675 # ginnasta
wd:Q13381572 # ginnasta artistica
wd:Q24037210 # ginnasta ritmica
wd:Q937857 # calciatrice
wd:Q13381863 # schermitrice
wd:Q10833314 # tennista
wd:Q4144610 # sciatrice alpina
wd:Q2887217 # pallacanestro femminile
wd:Q50995749 # personalità legata allo sport etc.
}
?item wdt:P166 ?medal .
VALUES ?medal {
wd:Q406039 # medaglia d'oro
wd:Q847956 # medaglia d'argento
wd:Q873364 # medaglia di bronzo
}
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
#FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P27 ?p27}
OPTIONAL {?item wdt:P19 ?p19}
OPTIONAL {?item wdt:P20 ?p20}
OPTIONAL {?item wdt:P166 ?p166}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 1000
}}
== [[Progetto:WikiDonne/Liste voci mancanti/Sportive/Atlete|Voci mancanti di sportive che praticano atletica leggera]] (V2) ==
{{SPARQL|query=SELECT DISTINCT ?item ?p27Label ?p19Label ?p20Label ?linkcount
WHERE {
?item wdt:P31 wd:Q5 . #istanza di umano
?item wdt:P21 wd:Q6581072 . #genere donna
?item wdt:P641 wd:Q542 . #sport praticato: atletica leggera
FILTER NOT EXISTS { #non ha voce in itwiki
?wen schema:about ?item .
?wen schema:isPartOf <https://it.wikipedia.org/> .
}
?item wikibase:sitelinks ?linkcount . #numero versioni linguistiche
FILTER (?linkcount > 3 ) .
OPTIONAL {?item wdt:P27 ?p27}
OPTIONAL {?item wdt:P19 ?p19}
OPTIONAL {?item wdt:P20 ?p20}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". } #label in italiano
}
ORDER BY DESC(?linkcount)
LIMIT 1000
}}
== Numero biografie di donne italiane in itwiki ==
{{SPARQL|query=
SELECT (COUNT(?sitelink) AS ?number)
WHERE {
?item wdt:P31 wd:Q5; #biografie=istanza umano
wdt:P27 wd:Q38; #paese di cittadinanza Italia
wdt:P21 wd:Q6581072. #genere donna
?sitelink schema:isPartOf <https://it.wikipedia.org/>;
schema:about ?item.
}
}}
== Donne nell'ambito medico ==
Item Wikidata, nominativo, foto se presente, numero voci nelle altre versioni linguistiche
{{SPARQL|query=
SELECT distinct ?item ?itemLabel ?pic ?linkcount WHERE {
?item wdt:P106 ?occ .
VALUES ?occ {
wd:Q55645123 #health care provider
wd:Q11974939 #health professional
wd:Q186360 #nurse
wd:Q39631 #phisician
wd:Q774306 #surgeon
wd:Q28837 #anesthesist
wd:Q6257322 #hygienist
wd:Q6261391 #infectious disease physician
wd:Q49881744 #intensivist
wd:Q7065152 #internist
wd:Q7414979 #epidemiologist
wd:Q6955703 #virologist
wd:Q8807931 #pulmonologist
wd:Q8804168 #psychiatrist
}
?sitelink schema:about ?item .
FILTER NOT EXISTS { ?wfr schema:about ?item . ?wfr schema:inLanguage "it" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P21 wd:Q6581072 . #gender:female
?item wdt:P31 wd:Q5 . #human
OPTIONAL {?item wdt:
OPTIONAL {?item wikibase:sitelinks ?linkcount .} #count of sitelinks
}
}}
Riga 388 ⟶ 811:
LIMIT 5000
}}
== Liste per paese di cittadinanza ==
Query di esempio per estrarre liste di nomi per paese di cittadinanza.
{| class="wikitable"
!Testo della query
!Descrizione (cosa fanno le singole righe)
|-
|{{SPARQL|query=SELECT ?item ?itemLabel ?itemDescription ?linkcount WHERE {
?item wdt:P21 wd:Q6581072.
?item wdt:P27 wd:Q45.
?item wikibase:sitelinks ?linkcount .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
FILTER NOT EXISTS { ?it schema:about ?item . ?it schema:inLanguage "it" }
FILTER(?linkcount > 5 )
}
ORDER BY DESC (?linkcount)
LIMIT 500}}
|style="display:inline-table; vertical-align:top;"| <pre>
#mostra (su Wikidata) item, etichetta, descrizione e numero di link di cose che sono
#genere: femmina
#paese di cittadinanza: Portogallo (è il Q45, basta cambiarlo...)
#mostra i sitelinks
#prende etichetta e descrizioni in italiano o inglese
#di tutto ciò che NON c'è su itwiki
#e che ha sitelinks>5
#mette in ordine decrescente di sitelinks
#e si ferma a 500 risultati...
</pre>
|}
[[Categoria:Progetto WikiDonne]]
| |||