快速入门：使用 Terraform 创建 Azure 自动化帐户

在本快速入门中，将创建 Azure 自动化帐户，并使用 Terraform 为该帐户分配“读者”角色。 自动化帐户是基于云的服务，为运行 runbook 提供安全的环境，runbook 是自动化进程的脚本。 帐户可以自动化在云中管理的频繁、耗时和易出错的任务。 此自动化帐户是在 Azure 资源组中创建的，该资源组是包含 Azure 解决方案相关资源的容器。 此外，“读者”角色被分配给自动化帐户，授予订阅权限以查看自动化帐户中的所有资源，但不进行任何更改。

Terraform 支持云基础结构的定义、预览和部署。 使用 Terraform，可以使用 HCL 语法创建配置文件。 利用 HCL 语法，可指定 Azure 这样的云提供程序和构成云基础结构的元素。 创建配置文件后，请创建一个执行计划，利用该计划，可在部署基础结构更改之前先预览这些更改。 验证了更改后，请应用该执行计划以部署基础结构。

在本文中，学习如何：

先决条件

• 创建具有活动订阅的 Azure 帐户。 可以 免费创建帐户。 新自动化帐户的选项组织在 Azure 门户的“创建自动化帐户”页面中的选项卡中。

• 安装和配置 Terraform。

实现 Terraform 代码

1. 创建用于测试和运行示例 Terraform 代码的目录，并将其设为当前目录。

2. 创建名为 main.tf 的文件并插入以下代码：

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     ___location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_string" "azurerm_automation_account_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_automation_account" "example" {
     name                = coalesce(var.automation_account_name, "autoacc-${random_string.azurerm_automation_account_name.result}")
     resource_group_name = azurerm_resource_group.rg.name
     ___location            = azurerm_resource_group.rg.___location
     sku_name            = "Basic"
     identity {
       type         = "SystemAssigned"
     }
   
     public_network_access_enabled = true
   }
   
   data "azurerm_subscription" "current" {}
   
   data "azurerm_role_definition" "contributor" {
     name = "Contributor"
   }
   
   resource "azurerm_role_assignment" "example" {
     scope              = data.azurerm_subscription.current.id
     role_definition_name = "Contributor"
     principal_id       = azurerm_automation_account.example.identity[0].principal_id
   }
   

3. 创建名为 outputs.tf 的文件并插入以下代码：

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "automation_account_name" {
     value = azurerm_automation_account.example.name
   }
   

4. 创建名为 providers.tf 的文件并插入以下代码：

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. 创建名为 variables.tf 的文件并插入以下代码：

   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "automation_account_name" {
     type        = string
     description = "The name of the Automation Account resource. The value will be randomly generated if blank."
     default     = ""
   }
   

初始化 Terraform

运行 terraform init 以初始化 Terraform 部署。 此命令将下载管理 Azure 资源所需的 Azure 提供程序。

terraform init -upgrade

要点：

• 参数 -upgrade 可将必要的提供程序插件升级到符合配置版本约束的最新版本。

创建 Terraform 执行计划

运行 terraform 计划 以创建执行计划。

terraform plan -out main.tfplan

要点：

• terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
• 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

应用 Terraform 执行计划

运行 terraform apply 将执行计划应用到云基础结构。

terraform apply main.tfplan

要点：

• 示例 terraform apply 命令假设你先前运行了 terraform plan -out main.tfplan。
• 如果为 -out 参数指定了不同的文件名，请在对 terraform apply 的调用中使用该相同文件名。
• 如果未使用 -out 参数，请调用不带任何参数的 terraform apply。

验证结果

清理资源

不再需要通过 Terraform 创建的资源时，请执行以下步骤：

1. 运行 terraform 计划 并指定 destroy 标志。

   terraform plan -destroy -out main.destroy.tfplan
   

   要点：

   • terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
   • 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

2. 运行 terraform apply 来应用执行计划。

   terraform apply main.destroy.tfplan
   

Azure 上的 Terraform 故障排除

排查在 Azure 上使用 Terraform 时的常见问题。

后续步骤

在本快速入门中，你创建了一个自动化帐户。 浏览有关自动化帐户的文章 以了解详细信息。

要在自动化帐户中使用托管标识，请继续：