快速入门：使用 Terraform 配置 Azure 虚拟网络网关

在本快速入门中，将使用 Terraform 创建以 Equinix 为服务提供商的 Azure ExpressRoute 线路。 线路使用带宽为 50 Mbps 的标准 SKU，对等互连位置为华盛顿特区。专用对等互连分别通过 192.168.10.16/30 和 192.168.10.20/30 的主子网和次子网启用。 脚本还创建了虚拟网络和高性能 ExpressRoute 网关。

使用 Terraform 可以定义、预览和部署云基础结构。 使用 Terraform 时，请使用 HCL 语法来创建配置文件。 利用 HCL 语法，可指定 Azure 这样的云提供程序和构成云基础结构的元素。 创建配置文件后，请创建一个执行计划，利用该计划，可在部署基础结构更改之前先预览这些更改。 验证了更改后，请应用该执行计划以部署基础结构。

在本文中，学习如何：

先决条件

• 创建具有活动订阅的 Azure 帐户。 你可以免费创建一个帐户。

• 安装和配置 Terraform。

实现 Terraform 代码

1. 创建用于测试和运行示例 Terraform 代码的目录，并将其设为当前目录。

2. 创建名为 main.tf 的文件并插入以下代码：

   # Create Resource Group
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     ___location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   # Random String for unique naming
   resource "random_string" "name" {
     length  = 8
     special = false
     upper   = false
     lower   = true
     numeric = false
   }
   
   # Create Virtual Network
   resource "azurerm_virtual_network" "vnet" {
     name                = "vnet-${random_string.name.result}"
     address_space       = ["10.0.0.0/16"]
     ___location            = azurerm_resource_group.rg.___location
     resource_group_name = azurerm_resource_group.rg.name
   }
   
   # Create Subnet for Gateway
   resource "azurerm_subnet" "gateway_subnet" {
     name                 = "GatewaySubnet"
     resource_group_name  = azurerm_resource_group.rg.name
     virtual_network_name = azurerm_virtual_network.vnet.name
     address_prefixes     = ["10.0.0.0/24"]
   }
   
   # Create Public IP for Gateway
   resource "azurerm_public_ip" "gateway_ip" {
     name                 = "pip-${random_string.name.result}"
     ___location            = azurerm_resource_group.rg.___location
     resource_group_name = azurerm_resource_group.rg.name
     allocation_method   = "Static"
     sku                 = "Standard"
   }
   
   # Create ExpressRoute Gateway
   resource "azurerm_virtual_network_gateway" "gateway" {
     name                 = "gateway-${random_string.name.result}"
     ___location            = azurerm_resource_group.rg.___location
     resource_group_name = azurerm_resource_group.rg.name
     type                = "ExpressRoute"
     vpn_type            = "RouteBased"
     active_active       = false
     enable_bgp          = false
     sku                 = "HighPerformance"
   
     ip_configuration {
       name                 = "vnetGatewayConfig"
       public_ip_address_id = azurerm_public_ip.gateway_ip.id
       subnet_id            = azurerm_subnet.gateway_subnet.id
     }
   }
   
   # Create ExpressRoute Circuit
   resource "azurerm_express_route_circuit" "circuit" {
     name                 = "erc-${random_string.name.result}"
     resource_group_name   = azurerm_resource_group.rg.name
     ___location              = azurerm_resource_group.rg.___location
     service_provider_name = "Equinix"
     peering_location      = "Washington DC"
     bandwidth_in_mbps     = 50
     sku {
       tier   = "Standard"
       family = "MeteredData"
     }
   }
   
   # Create ExpressRoute Circuit Peering
   resource "azurerm_express_route_circuit_peering" "private" {
     peering_type                  = "AzurePrivatePeering"
     express_route_circuit_name    = azurerm_express_route_circuit.circuit.name
     resource_group_name           = azurerm_resource_group.rg.name
     primary_peer_address_prefix   = "192.168.10.16/30"
     secondary_peer_address_prefix = "192.168.10.20/30"
     vlan_id                       = 200
     peer_asn                      = 65001 # Provide a valid private ASN here 
   }
   

3. 创建名为 outputs.tf 的文件并插入以下代码：

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "express_route_circuit_id" {
     value = azurerm_express_route_circuit.circuit.id
   }
   
   output "gateway_name" {
     value = azurerm_virtual_network_gateway.gateway.name
   }
   
   output "gateway_ip" {
     value = azurerm_public_ip.gateway_ip.ip_address
   }
   
   output "service_key" {
     value     = azurerm_express_route_circuit.circuit.service_key
     sensitive = true
   }
   

4. 创建名为 providers.tf 的文件并插入以下代码：

   terraform {
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

5. 创建名为 variables.tf 的文件并插入以下代码：

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   

初始化 Terraform

运行 terraform init，将 Terraform 部署进行初始化。 此命令将下载管理 Azure 资源所需的 Azure 提供程序。

terraform init -upgrade

要点：

• 参数 -upgrade 可将必要的提供程序插件升级到符合配置版本约束的最新版本。

创建 Terraform 执行计划

运行 terraform plan 以创建执行计划。

terraform plan -out main.tfplan

要点：

• terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
• 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

应用 Terraform 执行计划

运行 terraform apply，将执行计划应用到云基础结构。

terraform apply main.tfplan

要点：

• 示例 terraform apply 命令假设你先前运行了 terraform plan -out main.tfplan。
• 如果为 -out 参数指定了不同的文件名，请在对 terraform apply 的调用中使用该相同文件名。
• 如果未使用 -out 参数，请调用不带任何参数的 terraform apply。

验证结果

清理资源

不再需要通过 Terraform 创建的资源时，请执行以下步骤：

1. 运行 terraform plan 并指定 destroy 标志。

   terraform plan -destroy -out main.destroy.tfplan
   

   要点：

   • terraform plan 命令将创建一个执行计划，但不会执行它。 它会确定创建配置文件中指定的配置需要执行哪些操作。 此模式允许你在对实际资源进行任何更改之前验证执行计划是否符合预期。
   • 使用可选 -out 参数可以为计划指定输出文件。 使用 -out 参数可以确保所查看的计划与所应用的计划完全一致。

2. 运行 terraform apply 以应用执行计划。

   terraform apply main.destroy.tfplan
   

Azure 上的 Terraform 故障排除

排查在 Azure 上使用 Terraform 时遇到的常见问题。

后续步骤

查看有关 Azure 虚拟网络网关的更多文章。

若要了解如何将虚拟网络链接到线路，请继续学习 ExpressRoute 教程。